build.gradle

buildscript {
    repositories {
        jcenter()
        maven {url = "http://files.minecraftforge.net/maven"}
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT'
    }
}
apply plugin: 'net.minecraftforge.gradle.forge'

version = "${mc_version}-${mod_version}"
group = "rocks.gameonthe.rockytweaks"
archivesBaseName = "rockytweaks"

sourceCompatibility = targetCompatibility = "1.8"
compileJava {
    sourceCompatibility = targetCompatibility = "1.8"
    options.encoding = 'UTF-8'
}

minecraft {
    version = "${mc_version}-${forge_version}"
    runDir = "run"
    mappings = "${mcp_mappings}"
    makeObfSourceJar = false

    replaceIn 'ModInfo.java'
    replace '@NAME@', project.name
    replace '@VERSION@', project.mod_version
}

repositories {
    mavenLocal()
    mavenCentral()
    maven {url "http://maven.blamejared.com"}
    maven {url "http://dvs1.progwml6.com/files/maven"}
}

dependencies {
    compileOnly "mezz.jei:jei_${mc_version}:${jei_version}:api"
    runtime "mezz.jei:jei_${mc_version}:${jei_version}"
    compile "CraftTweaker2:CraftTweaker2-API:${ct_version}"
    compile "CraftTweaker2:CraftTweaker2-MC1120-Main:1.12-${ct_version}"
    compile "com.blamejared:MTLib:${mtlib_version}"
}

processResources {
    inputs.property "version", project.mod_version
    inputs.property "mcversion", project.minecraft.version
    inputs.property "name", project.name
    inputs.property "modid", project.archivesBaseName

    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
        expand ([
            'modid': project.archivesBaseName,
            'version': project.mod_version,
            'name': project.name,
            'mcversion': project.minecraft.version
        ])
    }
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}