addlicense/flake.nix at master · PerplexSystems/addlicense · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-23.05";
    devenv.url = "github:cachix/devenv";
  };

  outputs = { self, nixpkgs, devenv, } @ inputs:
    let
      # System types to support.
      supportedSystems = [ "x86_64-linux" "x86_64-darwin" "aarch64-darwin" ];

      # Helper function to generate an attrset '{ x86_64-linux = f "x86_64-linux"; ... }'.
      forAllSystems = nixpkgs.lib.genAttrs supportedSystems;

      # Nixpkgs instantiated for supported system types.
      nixpkgsFor = forAllSystems (system: import nixpkgs {
        inherit system;
      });

      package = pkgs:
        pkgs.buildGoModule {
          pname = "addlicense";
          version = "1.1.2";
          src = ./.;

          vendorHash = "sha256-2mncc21ecpv17Xp8PA9GIodoaCxNBacbbya/shU8T9Y=";

          subPackages = [ "." ];

          meta = with pkgs.lib; {
            description = "Ensures source code files have copyright license headers by scanning directory patterns recursively";
            homepage = "https://github.com/google/addlicense";
            license = licenses.asl20;
            maintainers = with maintainers; [ ratsclub ];
          };
        };
    in
    {
      overlays = {
        default = final: prev: {
          addlicense = package final;
        };
      };

      packages = forAllSystems (system:
        let pkgs = nixpkgsFor."${system}"; in {
          default = package pkgs;
        });

      devShells = forAllSystems (system:
        let
          pkgs = nixpkgsFor."${system}";
        in
        {
          default = devenv.lib.mkShell {
            inherit inputs pkgs;
            modules = [
              {
                languages.go.enable = true;
              }
            ];
          };
        });
    };
}