build.gradle

/*
 * This build file was auto generated by running the Gradle 'init' task
 * by 'tpm' at '10/29/16 7:27 PM' with Gradle 3.1
 *
 * This generated file contains a commented-out sample Java project to get you started.
 * For more details take a look at the Java Quickstart chapter in the Gradle
 * user guide available at https://docs.gradle.org/3.1/userguide/tutorial_java_projects.html
 */


// Apply the java plugin to add support for Java
apply plugin: 'java'
apply plugin: 'distribution'
apply plugin: 'com.github.johnrengelman.shadow'

subprojects {
    apply plugin: 'java'
    group = 'up.se2016'
    version = '1.0'
    repositories {
        jcenter()
    }
}

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.github.jengelman.gradle.plugins:shadow:1.2.3'
    }
}

dependencies {
    compile project(':gui')
}

shadowJar {
    manifest {
      attributes 'Main-Class': 'up.se2016.CalcGUI'
  }
}

jar {
  finalizedBy 'shadowJar'
}

javadoc {
    configure((CoreJavadocOptions) getOptions()) {
        addStringOption('sourcepath', project.hasProperty('jdkSrc') ? jdkSrc :
                "$System.env.JAVA_HOME/src")
        links 'https://docs.oracle.com/javase/8/docs/api/'
    }

    source project.subprojects.collect {it.sourceSets.main.allJava }
    classpath = files(project.subprojects.collect { it.sourceSets.main.compileClasspath })
}

distributions {
  main {
    contents {
      into ('docs') {
        from javadoc
      }
      from shadowJar
    }
  }
}