build.gradle

buildscript {
    ext {
        shadowJarVersion = '8.1.1'
    }
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath "com.github.johnrengelman:shadow:${shadowJarVersion}"
    }
}

plugins {
    id "com.github.ben-manes.versions" version '0.51.0'
    id 'com.adarshr.test-logger' version '4.0.0'
    id 'com.diffplug.spotless' version '6.25.0'
    id "com.github.spotbugs" version "6.0.25"
}

apply from: "$rootDir/gradle-scripts/extensions.gradle"
apply from: "$rootDir/gradle-scripts/plugins.gradle"
apply from: "$rootDir/gradle-scripts/project-info.gradle"
apply from: "$rootDir/gradle-scripts/java-compile.gradle"
apply from: "$rootDir/gradle-scripts/repositories.gradle"
apply from: "$rootDir/gradle-scripts/test.gradle"
apply from: "$rootDir/gradle-scripts/integration-tests.gradle"
apply from: "$rootDir/gradle-scripts/test-logger.gradle"
apply from: "$rootDir/gradle-scripts/set-library-version.gradle"


ext {
    mockitoVersion = '5.14.2'
    slf4jTestVersion = '1.2.0'
    assertjVersion = '3.26.3'
    pmdVersion = '7.7.0'
    jacocoVersion = '0.8.12'
    commercetoolsSyncJava = '10.0.5'
    httpClientVersion = '17.16.0'
    apacheCliVersion = '1.9.0'
    jupiterApiVersion = '5.11.3'
    logbackVersion = '1.5.12'
    logstashLogbackEncoderVersion= '7.4'
}

apply from: "$rootDir/gradle-scripts/spotless.gradle"
apply from: "$rootDir/gradle-scripts/pmd.gradle"
apply from: "$rootDir/gradle-scripts/jacoco.gradle"
apply from: "$rootDir/gradle-scripts/spotbugs.gradle"
apply from: "$rootDir/gradle-scripts/shadow.gradle"
apply from: "$rootDir/gradle-scripts/execution-order.gradle"

/**
 * 1. This cannot be in the "gradle-scripts/execution-order.gradle" script due to
 * "Script plugins do not have access to the main buildscript classpath.":
 * https://discuss.gradle.org/t/cant-access-classes-from-plugin-directly-in-included-script/14721/2
 *
 * 2. Cannot use normal dependsOn syntax due to https://github.com/diffplug/spotless/issues/198#issuecomment-363542192
 */

import com.diffplug.gradle.spotless.SpotlessTask
tasks.withType(SpotlessTask) {
    it.mustRunAfter compileIntegrationTestJava
    pmdMain.mustRunAfter it
}

dependencies {
    implementation "com.commercetools:commercetools-sync-java:${commercetoolsSyncJava}"
    implementation "com.commercetools.sdk:commercetools-okhttp-client4:${httpClientVersion}"
    implementation "commons-cli:commons-cli:${apacheCliVersion}"
    implementation "ch.qos.logback:logback-classic:${logbackVersion}"
    implementation "ch.qos.logback:logback-core:${logbackVersion}"
    implementation "net.logstash.logback:logstash-logback-encoder:${logstashLogbackEncoderVersion}"
    testImplementation "uk.org.lidalia:slf4j-test:${slf4jTestVersion}"
    testImplementation "org.mockito:mockito-core:${mockitoVersion}"
    testImplementation "org.junit.jupiter:junit-jupiter-api:${jupiterApiVersion}"
    testImplementation "org.junit.jupiter:junit-jupiter-params:${jupiterApiVersion}"
    testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:${jupiterApiVersion}"
    testImplementation "org.assertj:assertj-core:${assertjVersion}"
}