ui/edgy-nvim: init

docs/release-notes/rl-0.7.md

@@ -136,6 +136,7 @@ everyone.
 
 [ts-error-translator.nvim]: https://github.com/dmmulroy/ts-error-translator.nvim
 [credo]: https://github.com/rrrene/credo
+[edgy.nvim]: https://github.com/folke/edgy.nvim
 
 - Add `deno fmt` as the default Markdown formatter. This will be enabled
   automatically if you have autoformatting enabled, but can be disabled manually
@@ -187,6 +188,10 @@ everyone.
 - Add [python-lsp-server](https://github.com/python-lsp/python-lsp-server) as an
   additional Python LSP server.
 
+- Add support for [edgy.nvim]. This can be enabled with
+  [](#opt-vim.ui.edgy-nvim.enable). Support for `edgy.nvim` should be considered
+  **experimental** as it conflicts with other plugins that modify the UI.
+
 [ppenguin](https://github.com/ppenguin):
 
 - Telescope:

flake.nix

@@ -565,6 +565,11 @@
       flake = false;
     };
 
+    plugin-edgy-nvim = {
+      url = "github:folke/edgy.nvim";
+      flake = false;
+    };
+
     # Assistant
     plugin-chatgpt = {
       url = "github:jackMort/ChatGPT.nvim";

modules/plugins/filetree/neo-tree/neo-tree.nix

@@ -129,7 +129,7 @@ in {
         description = ''
           Must be either a boolean or a path to your log file.
 
-          Use :NeoTreeLogs to show the file
+          Use `:NeoTreeLogs` to show the file
         '';
       };
 
@@ -143,6 +143,7 @@ in {
         '';
       };
 
+      # https://github.com/folke/edgy.nvim/discussions/4
       open_files_do_not_replace_types = mkOption {
         type = listOf str;
         default = ["terminal" "Trouble" "qf" "edgy"];

modules/plugins/ui/default.nix

@@ -5,6 +5,7 @@
     ./notifications
     ./smartcolumn
     ./colorizer
+    ./edgy-nvim
     ./illuminate
     ./breadcrumbs
     ./borders

modules/plugins/ui/edgy-nvim/config.nix

@@ -0,0 +1,30 @@
+{
+  config,
+  lib,
+  ...
+}: let
+  inherit (lib.modules) mkIf;
+  inherit (lib.strings) optionalString;
+  inherit (lib.nvim.dag) entryBefore;
+  inherit (lib.nvim.lua) toLuaObject;
+
+  cfg = config.vim.ui.edgy-nvim;
+in {
+  config = mkIf cfg.enable {
+    vim = {
+      startPlugins = ["edgy-nvim"];
+      pluginRC.edgy-nvim = entryBefore ["basic"] ''
+        ${optionalString cfg.setRecommendedNeovimOpts ''
+          -- Neovim options recommended by upstream.
+          -- Views can only be fully collapsed with the global statusline.
+          vim.o.laststatus = 3
+          -- Default splitting will cause your main splits to jump when opening an edgebar.
+          -- To prevent this, set `splitkeep` to either `screen` or `topline`.
+          vim.o.splitkeep = "screen"
+        ''}
+
+        require('edgy').setup(${toLuaObject cfg.setupOpts})
+      '';
+    };
+  };
+}

modules/plugins/ui/edgy-nvim/default.nix

@@ -0,0 +1,6 @@
+{
+  imports = [
+    ./edgy-nvim.nix
+    ./config.nix
+  ];
+}

modules/plugins/ui/edgy-nvim/edgy-nvim.nix

@@ -0,0 +1,21 @@
+{lib, ...}: let
+  inherit (lib.options) mkOption mkEnableOption;
+  inherit (lib.types) bool;
+  inherit (lib.nvim.types) mkPluginSetupOption;
+in {
+  options.vim.ui.edgy-nvim = {
+    enable = mkEnableOption "edgy.nvim for predefined window layouts";
+    setRecommendedNeovimOpts = mkOption {
+      type = bool;
+      default = false;
+      description = ''
+        Whether nvf should set `vim.opt.laststatus` and `vim.opt.splitkeep` to
+        values recommended by upstream to ensure maximum compatibility.
+      '';
+    };
+
+    setupOpts = mkPluginSetupOption "edgy" {
+      animate.enabled = mkEnableOption "animation support. Requires an animation library such as `mini.animate`";
+    };
+  };
+}