Bazel support #8

Activity

1. mingxwa

   added

   enhancementNew feature or requestNew feature or request

   build

   on Jan 29, 2026
2. MoFHeka commented on Mar 18, 2026

   

   MoFHeka

   on Mar 18, 2026

   More actions

   A simple implementation
   //third_party/proxy/BUILD.bazel

   # Description:
   #   Proxy: Next Generation Polymorphism in C++.
   
   load("@rules_cc//cc:defs.bzl", "cc_library")
   
   licenses(["notice"])  # Apache 2
   
   exports_files(["LICENSE"])
   
   SUPPORTED_CPP_STANDARDS = [
       "20",
       "23",
       "2b",
       "26",
   ]
   
   [config_setting(
       name = "is_cpp" + v,
       values = {"cxxopt": "-std=c++" + v},
   ) for v in SUPPORTED_CPP_STANDARDS]
   
   cc_library(
       name = "proxy",
       hdrs = glob(["include/**/*.h"]),
       strip_include_prefix = "include",
       target_compatible_with = select(
           {":is_cpp" + v: [] for v in SUPPORTED_CPP_STANDARDS} |
           {"//conditions:default": ["@platforms//:incompatible"]},
       ),
       visibility = ["//visibility:public"],
   )

   //third_party/proxy/extensions.bzl

   """Proxy: Next Generation Polymorphism in C++."""
   
   load("//third_party/proxy:repositories.bzl", "proxy_repo")
   
   def _proxy_dep_impl(_ctx):
       proxy_repo()
   
   proxy_dep = module_extension(
       implementation = _proxy_dep_impl,
   )

   //third_party/proxy/extensions.bzl

   """Proxy: Next Generation Polymorphism in C++."""
   
   load("@bazel_tools//tools/build_defs/repo:git.bzl", "new_git_repository")
   
   def proxy_repo():
       new_git_repository(
           name = "proxy",
           remote = "https://github.com/ngcpp/proxy.git",
           commit = "bcbe0c792cd42cb48edfbbdb1e272255cbe73cae",
           build_file = "//third_party/proxy:BUILD.bazel",
       )

   MODULE.bazel

   # setting proxy for next generation polymorphism in C++
   proxy_deps = use_extension("//third_party/proxy:extensions.bzl", "proxy_dep")
   use_repo(proxy_deps, "proxy")
3. mingxwa

   closed this as completedin #40on Jun 2, 2026